<html>
<head>
<title>Welcome</title>
</head>
<body text=white bgcolor=black>
<center>
<p><br></p><p><br></p>
<%
rem **********************************************************************
rem * Instantiate the object
rem **********************************************************************
Set Image = Server.CreateObject("AspImage.Image")
rem **********************************************************************
rem * Set various font parameters
rem **********************************************************************
Image.FontColor = vbYellow
Image.Italic = True
Image.Bold = True
Image.FontName = "Arial"
Image.FontSize = 14
Image.PadSize = 10
rem **********************************************************************
rem * Calculate the size of the text info is and set the image to this size
rem * (this has to be done since we want to fill the area with a gradient)
rem **********************************************************************
strMessage = "Welcome to"
Image.MaxX = Image.TextWidth (strMessage)
Image.MaxY = Image.TextHeight (strMessage)
rem **********************************************************************
rem * Create a one way gradient that starts with Red and ends with White
rem **********************************************************************
Image.GradientOneWay vbRed, vbWhite, 0
rem **********************************************************************
rem * Print our text to the image at the current X,Y position using 3D
rem **********************************************************************
Image.TextOut strMessage, Image.X, Image.Y, true
Image.BackgroundColor = vbBlack
rem **********************************************************************
rem * Set the filename and save
rem * NOTE: You should gen the filename dynamically for multiuser usage
rem **********************************************************************
Image.FileName = "d:\inetpub\wwwroot\images\msg1.jpg"
'Image.ImageFormat = 3
'Image.FileName = "d:\inetpub\wwwroot\images\msg1.png"
Image.SaveImage
rem **********************************************************************
rem * Write the <img src> tag out for the browser to pick up
rem **********************************************************************
Response.Write "<img src=""/images/msg1.jpg""><br>"
'Response.Write "<img src=""/images/msg1.png""><br>"
rem **********************************************************************
rem *
rem * We'll write a couple of other images using the same techniques to
rem * show a few variations
rem *
rem **********************************************************************
rem **********************************************************************
rem * Here's image #2
rem **********************************************************************
strMessage = "The Widget Factory"
Image.MaxX = Image.TextWidth (strMessage)
Image.MaxY = Image.TextHeight (strMessage)
Image.GradientTwoWay vbBlue, vbWhite, 1, 1
Image.TextOut strMessage, Image.X, Image.Y, true
Image.FileName = "d:\inetpub\wwwroot\images\msg2.jpg"
Image.SaveImage
Response.Write "<img align=top src=""/images/msg2.jpg"">"
rem **********************************************************************
rem * Here's image #3
rem **********************************************************************
Image.Bold = True
Image.FontName = "Arial"
Image.FontSize = 10
Image.PadSize = 3
Image.BackgroundColor = vbBlack
Image.FontColor = vbGreen
strMessage = "The Place for All Your Widget Needs"
Image.MaxX = Image.TextWidth (strMessage)
Image.MaxY = Image.TextHeight (strMessage)
rem Image.ClearImage
Image.TextOut strMessage, Image.X, Image.Y, false
Image.FileName = "d:\inetpub\wwwroot\images\msg3.jpg"
Image.SaveImage
Response.Write "<br><img align=top src=""/images/msg3.jpg"">"
rem **********************************************************************
rem * These properties give eval/registration information for the component
rem **********************************************************************
Response.Write "<p>Expires: " & Image.Expires
Response.Write "<br>Version: " & Image.Version
Response.Write "<br>Registered To: " & Image.RegisteredTo
Set Image = nothing
%>
</center>
</body>
</html>